| Kyle Swenson | 8d8f654 | 2021-03-15 11:02:55 -0600 | [diff] [blame^] | 1 | #include <asm-generic/vmlinux.lds.h> |
| 2 | #include <asm/page.h> |
| 3 | |
| 4 | OUTPUT_FORMAT(ELF_FORMAT) |
| 5 | OUTPUT_ARCH(ELF_ARCH) |
| 6 | ENTRY(_start) |
| 7 | jiffies = jiffies_64; |
| 8 | |
| 9 | SECTIONS |
| 10 | { |
| 11 | /* This must contain the right address - not quite the default ELF one.*/ |
| 12 | PROVIDE (__executable_start = START); |
| 13 | /* Static binaries stick stuff here, like the sigreturn trampoline, |
| 14 | * invisibly to objdump. So, just make __binary_start equal to the very |
| 15 | * beginning of the executable, and if there are unmapped pages after this, |
| 16 | * they are forever unusable. |
| 17 | */ |
| 18 | __binary_start = START; |
| 19 | |
| 20 | . = START + SIZEOF_HEADERS; |
| 21 | |
| 22 | _text = .; |
| 23 | INIT_TEXT_SECTION(0) |
| 24 | . = ALIGN(PAGE_SIZE); |
| 25 | |
| 26 | .text : |
| 27 | { |
| 28 | _stext = .; |
| 29 | TEXT_TEXT |
| 30 | SCHED_TEXT |
| 31 | LOCK_TEXT |
| 32 | *(.fixup) |
| 33 | /* .gnu.warning sections are handled specially by elf32.em. */ |
| 34 | *(.gnu.warning) |
| 35 | *(.gnu.linkonce.t*) |
| 36 | } |
| 37 | |
| 38 | . = ALIGN(PAGE_SIZE); |
| 39 | .syscall_stub : { |
| 40 | __syscall_stub_start = .; |
| 41 | *(.__syscall_stub*) |
| 42 | __syscall_stub_end = .; |
| 43 | } |
| 44 | |
| 45 | /* |
| 46 | * These are needed even in a static link, even if they wind up being empty. |
| 47 | * Newer glibc needs these __rel{,a}_iplt_{start,end} symbols. |
| 48 | */ |
| 49 | .rel.plt : { |
| 50 | *(.rel.plt) |
| 51 | PROVIDE_HIDDEN(__rel_iplt_start = .); |
| 52 | *(.rel.iplt) |
| 53 | PROVIDE_HIDDEN(__rel_iplt_end = .); |
| 54 | } |
| 55 | .rela.plt : { |
| 56 | *(.rela.plt) |
| 57 | PROVIDE_HIDDEN(__rela_iplt_start = .); |
| 58 | *(.rela.iplt) |
| 59 | PROVIDE_HIDDEN(__rela_iplt_end = .); |
| 60 | } |
| 61 | |
| 62 | #include <asm/common.lds.S> |
| 63 | |
| 64 | __init_begin = .; |
| 65 | init.data : { INIT_DATA } |
| 66 | __init_end = .; |
| 67 | |
| 68 | .data : |
| 69 | { |
| 70 | INIT_TASK_DATA(KERNEL_STACK_SIZE) |
| 71 | . = ALIGN(KERNEL_STACK_SIZE); |
| 72 | *(.data..init_irqstack) |
| 73 | DATA_DATA |
| 74 | *(.gnu.linkonce.d*) |
| 75 | CONSTRUCTORS |
| 76 | } |
| 77 | .data1 : { *(.data1) } |
| 78 | .ctors : |
| 79 | { |
| 80 | *(.ctors) |
| 81 | } |
| 82 | .dtors : |
| 83 | { |
| 84 | *(.dtors) |
| 85 | } |
| 86 | |
| 87 | .got : { *(.got.plt) *(.got) } |
| 88 | .dynamic : { *(.dynamic) } |
| 89 | .tdata : { *(.tdata .tdata.* .gnu.linkonce.td.*) } |
| 90 | .tbss : { *(.tbss .tbss.* .gnu.linkonce.tb.*) *(.tcommon) } |
| 91 | /* We want the small data sections together, so single-instruction offsets |
| 92 | can access them all, and initialized data all before uninitialized, so |
| 93 | we can shorten the on-disk segment size. */ |
| 94 | .sdata : { *(.sdata) } |
| 95 | _edata = .; |
| 96 | PROVIDE (edata = .); |
| 97 | . = ALIGN(PAGE_SIZE); |
| 98 | __bss_start = .; |
| 99 | PROVIDE(_bss_start = .); |
| 100 | SBSS(0) |
| 101 | BSS(0) |
| 102 | __bss_stop = .; |
| 103 | _end = .; |
| 104 | PROVIDE (end = .); |
| 105 | |
| 106 | STABS_DEBUG |
| 107 | |
| 108 | DWARF_DEBUG |
| 109 | |
| 110 | DISCARDS |
| 111 | } |